Listing 2: Code to Display Folders from the Startup Folders Group on the Outlook Bar
NONEXECUTABLE: To obtain the executable file, download the Zip file from the opening page of the article.

Sub ShowMyFolders()
    Dim objApp As Application
    Dim objOB As OutlookBarPane
    Dim objOBGroup As OutlookBarGroup
    Dim objShortcut As OutlookBarShortcut
    Dim colShortcuts As OutlookBarShortcuts
    Dim objExpl As Explorer
 
    Set objApp = CreateObject("Outlook.Application")
    Set objOB = objApp.ActiveExplorer.Panes.Item("OutlookBar")
    Set objOBGroup = objOB.Contents.Groups.Item("Startup Folders")
 
    If Not objOBGroup Is Nothing Then
        Set colShortcuts = objOBGroup.Shortcuts
        If colShortcuts.Count > 0 Then
            For Each objShortcut In colShortcuts
                If TypeName(objShortcut.Target) = "MAPIFolder" Then
                    Set objExpl = objApp.Explorers.Add(objShortcut.Target, _
                                    olFolderDisplayNoNavigation)
                    objExpl.Activate
                    objExpl.WindowState = olMinimized
                End If
            Next
        End If
    End If
 
    ' release objects
    Set objExpl = Nothing
    Set objShortcut = Nothing
    Set colShortcuts = Nothing
    Set objOBGroup = Nothing
    Set objOB = Nothing
    Set objApp = Nothing
End Sub