Subscribe to Windows IT Pro

 

Get Newsletters

  • Get the Latest News
  • Product Updates
  • Helpful Tricks
  • Productivity Tips

Subscribe Now!

November 21, 2005 12:00 AM

How can I update all profiles on a machine even if they're not currently loaded?

Windows IT Pro
InstantDoc ID #48506
Rating: (0)

A. In the FAQ "How can I update a registry value for all users on a machine?" at http://www.windowsitpro.com/Article/ArticleID/48128/48128.html , I explain how to enumerate HKEY_USERS and update each profile with a registry change; however, that change works only for profiles that are loaded. For example, if I have 100 profiles stored on a machine, they're not all loaded all the time under HKEY_USERS. Therefore, my original code would have updated only currently logged-on users or profiles that had processes still running under them or the well-known built-in credentials (NT System, Local Service, and Network Service) that are always loaded. You should test this code to ensure that it behaves as expected, especially if you run it when a user might log on because it could cause a new profile to be created for the user. I typically use this method as part of an OS upgrade scenario when I want to set something initially or outside of Group Policy for the existing profiles on a machine before user logon is possible.

I've created a script that takes a different approach to updating profiles. The code, which you can download at http://www.windowsitpro.com/content/content/48506/updateprof.zip enumerates the "Documents and Settings" folder and, for each subfolder (a profile), mounts the ntuser.dat file, modifies the file, unloads it, then moves to the next subfolder. The code also changes the desktop wallpaper, but you can obviously change the actual "work" that the script performs.


Dim objFSO, oShell, strBasePath, objFolder, objSubFolders, objSubFolder, strRun, nRtn
Dim strKeyPath, strKeyPathUser
const HKEY_USERS = &H80000003

Set objFSO = CreateObject("Scripting.FileSystemObject")

strKeyPath = "\Control Panel\PowerCfg\GlobalPowerPolicy" 

Set oShell = WScript.CreateObject("WScript.Shell") 
strBasePath = oShell.ExpandEnvironmentStrings("%ALLUSERSPROFILE%") 
strBasePath = left(strBasePath,InStrRev(strBasePath,"\")-1)
wscript.echo strBasePath

Dim binValue() 
strComputer = "." 

Set objReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\default:StdRegProv") 


Set objFolder = objFSO.GetFolder(strBasePath)
Set objSubFolders = objFolder.SubFolders
For Each objSubFolder in objSubFolders
    Wscript.Echo objSubFolder.Name
    If objFso.FileExists(strBasePath & "\" & objSubFolder.Name & "\" & "ntuser.dat") = True Then
        strRun = "REG.EXE load " & "HKU\TempHive " & Chr(34) & strBasePath & "\" & objSubFolder.Name & "\" & "ntuser.dat" & Chr(34)
        nRtn = oShell.Run(strRun, 1, True) 

        ' The work portion. Change this to anything task you want to perform.
        if objReg.GetBinaryValue(HKEY_USERS, "TempHive" & strKeyPath, "Policies", binValue) = 0 then 
            objReg.GetStringValue HKEY_USERS, "TempHive\Software\Microsoft\Windows\CurrentVersion\Explorer", "Logon User Name", userName 
            Wscript.Echo "Updating username " & userName 
            binValue(51)=128 
            objReg.SetBinaryValue HKEY_USERS, "TempHive" & strKeyPath, "Policies", binValue 
            objReg.SetStringValue HKEY_USERS, "TempHive\Control Panel\Desktop" , "Wallpaper", "D:\Multimedia\Images\Space\rocks.bmp"
            objReg.SetStringValue HKEY_USERS, "TempHive\Control Panel\Desktop" , "WallpaperStyle", "2"
        end if 
        ' End of the work portion

        strRun = "REG.EXE unload HKU\TempHive"
        nRtn = oShell.Run(strRun, 1, True) 
    End If
Next
You should run the script under the system context so that it has write access to everyone's profile (e.g., run it as a scheduled job). Also, instead of enumerating "Documents and Settings," you can enumerate HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\ProfileList and read the list of profiles.

Thanks to Toby Ovod-Everett for pointing out the limitation in my previous FAQ.

Related Content:

ARTICLE TOOLS

Comments
    There are no comments to display. Be the first one!
You must log on before posting a comment.

Are you a new visitor? Register Here

advertisement

advertisement

White Papers

Get your Windows 7 deployment off to the right start by implementing PC lockdown. A locked-down environment is easier and cheaper to support since users are less likely to make unnecessary changes to the core system configuration - read more here!

Essential Guides

Is your iSCSI "lossy"? The reality is that most off-the-shelf Ethernet hardware deployed for iSCSI can lose packets, resulting in slow performance or application downtime. Learn how to assess your current iSCSI infrastructure and engineer an advanced iSCSI SAN infrastructure.

Web Seminars

What's the best way to keep your network safe from malware? In this web seminar, security expert Greg Shields suggests an alternative method to the traditional blacklisting approach that is common with anti-virus and anti-malware solutions.

eLearning Series

We bring the experts direct to you to share their real-world perspective and expertise. During each event, three sessions stream in real time, so you can learn, ask questions, and get solutions.
Upcoming event: Getting the Most with Exchange 2010 with Paul Robichaux

Subscribe to Windows IT Pro!

Windows is a trademark of the Microsoft group of companies. Windows IT Pro is used by Penton Media Inc. under license from owner.